<xsl:template match="processing-instruction()[name(.)='tex']">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template name="verbatim-lineBreak">
  <xsl:param name="id"/>
  <xsl:text>\mbox{}\newline 
</xsl:text>
</xsl:template>

<xsl:template name="verbatim-createElement">
  <xsl:param name="name"/>
  <xsl:param name="special"/>
  <xsl:text>\textbf{</xsl:text>
  <xsl:value-of select="$name"/>
  <xsl:text>}</xsl:text>
</xsl:template>

<xsl:template name="verbatim-newLine"/>

<xsl:template name="verbatim-Text">
  <xsl:param name="words"/>
  <xsl:choose>
    <xsl:when test="lang('zh-TW') or lang('zh')">
      <xsl:text>{\textChinese </xsl:text>
      <xsl:value-of select="tei:escapeCharsVerbatim($words)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="lang('ja')">
      <xsl:text>{\textJapanese {</xsl:text>
      <xsl:value-of select="tei:escapeCharsVerbatim($words)"/>
      <xsl:text>}}</xsl:text>
    </xsl:when>
    <xsl:when test="lang('ko')">
      <xsl:text>{\textKorean </xsl:text>
      <xsl:value-of select="tei:escapeCharsVerbatim($words)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <!-- wrap RTL languages in an \hbox, see #442 -->
    <xsl:when test="lang('ar') or lang('he') or lang('fa') or lang('ur') or lang('sd')">
      <xsl:text>\hbox{</xsl:text>
      <xsl:value-of select="tei:escapeCharsVerbatim($words)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="tei:escapeCharsVerbatim($words)"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="nsList">
  <xsl:variable name="ns">
    <all>
      <names>
        <xsl:apply-templates select="." mode="ns"/>
      </names>
      <text>
        <xsl:copy-of select="."/>
      </text>
    </all>
  </xsl:variable>
  <xsl:for-each select="$ns/all/names">
    <xsl:for-each-group select="ns" group-by="@name">
      <xsl:if test="key('NSUsed',@value)">
        <xsl:call-template name="verbatim-lineBreak">
          <xsl:with-param name="id">22</xsl:with-param>
        </xsl:call-template>
        <xsl:sequence select="concat('   xmlns:',@name,'=',$dq,tei:escapeCharsVerbatim(@value),$dq)"/>
      </xsl:if>
    </xsl:for-each-group>
  </xsl:for-each>
</xsl:template>

<xsl:template name="NamespaceURI">
  <xsl:param name="uri"/>
  <xsl:value-of select="tei:escapeCharsVerbatim($uri)"/>
</xsl:template>

<xsl:template name="emphasize">
  <xsl:param name="class"/>
  <xsl:param name="content"/>
  <xsl:choose>
    <xsl:when test="$class='titlem' and tei:findLanguage(.) = 'ja'">
      <xsl:text>{\textJapanese {</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>}}</xsl:text>
    </xsl:when>
    <xsl:when test="$class='titlem' and tei:findLanguage(.) = 'ko'">
      <xsl:text>{\textKorean {</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>}}</xsl:text>
    </xsl:when>
    <xsl:when test="$class='titlem' and tei:findLanguage(.) = ('zh','zh-TW')">
      <xsl:text>{\textChinese {</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>}}</xsl:text>
    </xsl:when>
    <xsl:when test="$class='titlem'">
      <xsl:text>\textit{</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$class='titlej'">
      <xsl:text>\textit{</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$class='titlea'">
      <xsl:text>‘</xsl:text>
      <xsl:copy-of select="$content"/>
      <xsl:text>’</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="$content"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="Text">
  <xsl:param name="words"/>
  <xsl:value-of select="tei:escapeChars($words,.)"/>
</xsl:template>

<xsl:template name="applyRendition"/>

<xsl:template match="text()" mode="eg">
  <xsl:choose>
    <xsl:when test="starts-with(.,'
')">
      <xsl:value-of select="substring-after(.,'
')"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="."/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="makeSpan">
  <xsl:apply-templates/>
</xsl:template>

<xsl:template name="makeInline">
  <xsl:param name="before"/>
  <xsl:param name="style"/>
  <xsl:param name="after"/>
  <xsl:value-of select="$before"/>
  <xsl:sequence select="tei:makeHyperTarget(@xml:id)"/>
  <xsl:choose>
    <xsl:when test="$style=('add','unclear','bibl','docAuthor','titlem','italic','mentioned','term','foreign') and not(tei:findLanguage(.) = ('ja','ko','zh','zh-TW'))">
      <xsl:text>\textit{</xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style=('add','unclear','bibl','docAuthor','titlem','italic','mentioned','term','foreign') and tei:findLanguage(.) = 'ja'">
      <xsl:text>{\textJapanese </xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style=('add','unclear','bibl','docAuthor','titlem','italic','mentioned','term','foreign') and tei:findLanguage(.) = 'ko'">
      <xsl:text>{\textKorean </xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style=('add','unclear','bibl','docAuthor','titlem','italic','mentioned','term','foreign') and tei:findLanguage(.) = ('zh','zh-TW')">
      <xsl:text>{\textChinese </xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style='supplied'">
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
    </xsl:when>
    <xsl:when test="$style='bold'">
      <xsl:text>\textbf{</xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style='strikethrough'">
      <xsl:text>\sout{</xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style='sup'">
      <xsl:text>\textsuperscript{</xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="$style='sub'">
      <xsl:text>\textsubscript{</xsl:text>
      <xsl:value-of select="tei:escapeChars(normalize-space(.),.)"/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="local-name()='label'">
      <xsl:text>\textbf{</xsl:text>
      <xsl:apply-templates/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:when test="not($style)">
      <xsl:sequence select="concat('{\',local-name(),' ')"/>
      <xsl:apply-templates/>
      <xsl:text>}</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:sequence select="concat('{\',$style[1], ' ')"/>
      <xsl:apply-templates/>
      <xsl:text>}</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
  <xsl:value-of select="$after"/>
</xsl:template>

<xsl:template name="horizontalRule">
  <xsl:text>\\\rule[0.5ex]{\textwidth}{0.5pt}</xsl:text>
</xsl:template>

<xsl:template name="makeBlock">
  <xsl:param name="style"/>
  <xsl:sequence select="concat('\begin{',$style,'}')"/>
  <xsl:sequence select="tei:makeHyperTarget(@xml:id)"/>
  <xsl:apply-templates/>
  <xsl:sequence select="concat('\end{',$style,'}')"/>
</xsl:template>

<xsl:template name="makeSection">
  <xsl:param name="level"/>
  <xsl:param name="heading"/>
  <xsl:param name="implicitBlock">false</xsl:param>
  <xsl:text>
</xsl:text>
  <xsl:choose>
    <xsl:when test="$level=1">\section</xsl:when>
    <xsl:when test="$level=2">\subsection</xsl:when>
    <xsl:when test="$level=3">\subsubsection</xsl:when>
    <xsl:when test="$level=4">\paragraph</xsl:when>
  </xsl:choose>
  <xsl:text>{</xsl:text>
  <xsl:value-of select="$heading"/>
  <xsl:text>}
</xsl:text>
  <xsl:choose>
    <xsl:when test="$implicitBlock='true'">
      <xsl:text>\par
</xsl:text>
      <xsl:apply-templates/>
      <xsl:text>\par
</xsl:text>
    </xsl:when>
    <xsl:when test="*">
      <xsl:apply-templates/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text>\par
</xsl:text>
      <xsl:apply-templates/>
      <xsl:text>\par
</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="makeWithLabel">
  <xsl:param name="before"/>
  <xsl:text>\textit{</xsl:text>
  <xsl:value-of select="$before"/>
  <xsl:text>}: </xsl:text>
  <xsl:apply-templates/>
</xsl:template>

<xsl:param name="outputTarget">latex</xsl:param>

<xsl:param name="documentclass">article</xsl:param>

<xsl:param name="spaceCharacter">\hspace*{6pt}</xsl:param>

<xsl:variable name="top" select="/"/>

<xsl:function name="tei:escapeCharsVerbatim" as="xs:string">
  <xsl:param name="letters"/>
  <xsl:value-of select="replace(replace(replace(replace(replace(translate($letters, '\{}','⃥❴❵'),     '
','\\newline
'),     '_','\\textunderscore '),     '\^','\\textasciicircum '),     '~','\\textasciitilde '),     '([%&\$#])','\\$1')"/>
</xsl:function>

<xsl:function name="tei:escapeChars" as="xs:string" override-extension-function="yes">
  <xsl:param name="letters"/>
  <xsl:param name="context"/>
  <xsl:value-of select="replace(replace(replace(replace(replace(translate($letters,'ſ
','s '),      '\\','\\textbackslash '),     '_','\\textunderscore '),     '\^','\\textasciicircum '),     '~','\\textasciitilde '),     '([\}\{%&\$#])','\\$1')"/>
</xsl:function>

<xsl:function name="tei:escapeCharsPartial" as="xs:string" override-extension-function="yes">
  <xsl:param name="letters"/>
  <xsl:value-of select="replace($letters,'([%#])','\\$1')"/>
</xsl:function>

<xsl:function name="tei:makeHyperTarget" as="xs:string">
  <xsl:param name="id"/>
  <xsl:value-of select=" if ($id) then concat('\label{',$id,'}') else ''"/>
</xsl:function>

<xsl:output method="text" encoding="utf8"/>